Linker Relocation

000000000014  000400000017 R_RISCV_PCREL_HI2 0000000000000000 hello_msg + 0

表示

  14:   00000517                auipc   a0,0x0

这条指令在重定位时需要用 hello_msg 的真正地址的高 20 位与 pc 的高 20 位的差值
写到原指令中 (00000517) 的 imm 部分.

编译 c 代码时使用 `-mcmodel=medany` 会使用 PCREL_HI20

000000000018  000500000018 R_RISCV_PCREL_LO1 0000000000000014 .1 + 0

对应

  18:   00050513                mv      a0,a0

R_RISCV_PCREL_LO12 比较特殊的一点是它使用的 symbol 是前面 R_RISCV_PCREL_HI2 对应的 label, 例如:

1:
    auipc a0, %pcrel_hi(hello_msg)
    addi a0, a0, %pcrel_lo(1b)
    # NOTE: 使用了 1b 而不是 hello_msg

处理 auipc 时会通过 `riscv_record_pcgp_hi_reloc` 记录下 `hello_msg` 的 pc-relative 地址 (1b 为 key). 后面处理 addi 时通过 `_bfd_riscv_relax_pc` 根据 `1b` 找到前面记录的 hi_reloc 及 `hello_msg` 的 pc-relative 地址并取其低12 位.

之所以这样而不直接写成 `addi xx, xx, %pcrel_lo(symbol)` 是处理 `addi` 时需要相对于前面的 `auipc` 计算 pc-relative (而不是相对于 addi 本身), 因此采取这种复杂的方式

000000000004  00040000001a R_RISCV_HI20      0000000000000000 hello_msg + 0

表示

   4:   00000537                lui     a0,0x0

这条指令的 imm 部分应该用 hello_msg 的真正地址的高 20 位直接填充

编译 c 代码时使用 `-mcmodel=medlow` 时会使用 HI20

0000000000000024  0000000500000014 R_RISCV_GOT_HI20       0000000000000000 hello_msg + 0

对应

  24:   00000517                auipc   a0,0x0

GOT_HI20 与 PCREL_HI20 类似, 不同的是 GOT_HI20 并不是使用的 hello_msg 的地址, 而是 hello_msg 所在的 GOT 表项的地址, 因为 GOT 主要是为了解决动态链接时 static linker 无法确定符号地址的问题 (需要注意两点: 1. 静态链接也可以用 GOT, 但没有必要;

1. 动态链接也可以不用 GOT 而是让 rtld 直接 patch 代码本身, 参考 PIE)

编译 c 代码时使用 `-fPIC` 时会使用 GOT_HI20

JAL 的操作数也是一个 symbol, 但根据 symbol 的位置, 分为两种情况:

1. symbol 在当前 section
2. symbol 在其它 section

之所以区分这两种情况, 是因为 section 的地址是不确定的 (Linker Script 可以配置 section 的地址). 但如果 symbol 在当前 section, 因为 jal 的操作数是 PCREL 的, 所以操作数会是确定的值.

symbol 在同一个 section:

    .global _start
    .section .text
_start:
    jal here

here:
    ret

$> /opt/riscv/bin/riscv-elf-gcc test.S -O0 -c
$> /opt/riscv/bin/riscv-elf-objdump -d test.o

Disassembly of section .text:

0000000000000000 <_start>:
   0:   004000ef                jal     ra,4 <here>

0000000000000004 <here>:
   4:   8082                    ret

symbol 不在同一个 section:

    .global _start
    .section .text
_start:
    jal here

    .section .mysection
here:
    ret

$> riscv64-linux-gnu-objdump -d test.o

Disassembly of section .text:

0000000000000000 <_start>:
   0:   000000ef                jal     ra,0 <_start>

$> readelf -a test.o

Relocation section '.rela.text' at offset 0x100 contains 1 entry:
  Offset          Info           Type           Sym. Value    Sym. Name + Addend
000000000000  000400000011 R_RISCV_JAL       0000000000000000 here + 0

R_RISCV_JAL 的 IMM 编码参考 ENCODE_JTYPE_IMM 以及 JAL 的指令格式, 另外, IMM 编码决定了 JAL 跳转的范围在 [-1M,1M] 之间, 所以下面的代码会链接不过

    .global _start
    .section .text
_start:
    jal here
    ## 看起来像 ld 的 bug: jal 的跳转范围应该是 [-1m,1m], 但
    ## 这里显示是 [-0.5m,0.5m]...
    ## .rept 0x7ffff-1 可以链接通过
    .rept 0x7ffff
    .byte   0
    .endr
here:
    ret

$> riscv64-linux-gnu-gcc test.S  -nostdlib -O0
/tmp/ccuebMtl.o: in function `_start':
(.text+0x0): relocation truncated to fit: R_RISCV_JAL against `here'
collect2: error: ld returned 1 exit status

这个和 Linker Relaxation 有关

前面的 relocate type 都是 patch 的指令的一部分, R_RISCV_64 patch 的是整个 64 位数据, 例如下面的例子:

$> cat test.s
    .section .text
    .globl _start
_start:
    la a0, hello
    ld a0, 0(a0)

.section .data
hello:
    .dword hello

$> riscv-gcc test.s -c
$> riscv-objdump -r ./test.o

./test.o:     file format elf64-littleriscv

RELOCATION RECORDS FOR [.text]:
OFFSET           TYPE              VALUE
0000000000000000 R_RISCV_PCREL_HI20  hello
0000000000000000 R_RISCV_RELAX     *ABS*
0000000000000004 R_RISCV_PCREL_LO12_I  .L0
0000000000000004 R_RISCV_RELAX     *ABS*


RELOCATION RECORDS FOR [.data]:
OFFSET           TYPE              VALUE
,----
| 0000000000000000 R_RISCV_64        hello
`----

另外, 与一般的 reloc type 不同, R_RISCV_64 需要 patch 的地址并非指令, 因此在 riscv 中需要考虑 endianness 的影响. 实际上, 给 riscv 添加 big-endian 支持的 patch 中, 有相当一部分代码是修改 assember/linker, 让它们能处理类似 R_RISCV_64 这样的 reloc type

R_RISCV_64 可以用来实现超长跳转:

# 假设 main 离 _start 特别远, 无论其绝对地址或者 pc 相对地址都超过了 32 位
_start:
    la t0, trampoline
    ld t0, 0(t0)
    jalr ra, t0

trampoline:
    # main 的 relocation type 为 R_RISCV_64
    main

通过 ADD/SUB, 编译时可以通过 linker 对 label 做有限的运算

$> cat test.s

.section .text
    .globl _start
_start:
    la a0, hello
    ld a0, 0(a0)

    .section .data
hello:
    .dword  hello - _start

$> riscv-gcc test.s -c
$> riscv-objdump -r test.o

test.o:     file format elf64-littleriscv

RELOCATION RECORDS FOR [.text]:
OFFSET           TYPE              VALUE
0000000000000000 R_RISCV_PCREL_HI20  hello
0000000000000000 R_RISCV_RELAX     *ABS*
0000000000000004 R_RISCV_PCREL_LO12_I  .L0
0000000000000004 R_RISCV_RELAX     *ABS*


RELOCATION RECORDS FOR [.data]:
OFFSET           TYPE              VALUE
,----
| 0000000000000000 R_RISCV_ADD64     hello
| 0000000000000000 R_RISCV_SUB64     _start
`----

上面的例子中 value 为 0x10801, 但 RISCV_CONST_HIGH_PART 返回的值为 0x11, 而不是 0x10, 因为低 12 位 0x801 无法用 12 位 sign extened 表示.

正常情况下 RISCV_CONST_HIGH_PART 的逻辑应该类似于这样:

if msb(low(value)) == 0:
    high_part = hi(value)
else:
    high_part = hi(value) + 1

之所以加 1, 是因为后面的 ENCODE_ITYPE_IMM 会直接把 uint12_t 0x801 转换为 int12_t, 但是把 unsigned A 转换为 signed 相当于 A-(1<<12) (例如时钟的 8 点做为负数解释是 -4 点, 即 8-12点), 所以 high_part 需要加上 1.

所以 0x10801 的 high_part 为 0x11

具体实现上 `msb 为 1 则 high_part 加 1` 可以通过 `msb 加 1 后进位` 实现.

#define RISCV_CONST_HIGH_PART(VALUE) (((VALUE) + (1 << 11)) & 0xfffff)

如前面所述, ENCODE_ITYPE_IMM 直接取低 12 bit, 即使它被 `错误的` extened 成负数

/* 即低 12 bit, 然后右移 20 bit, 因为 I 指令的 imm 在指令的高 20 bit */
#define ENCODE_ITYPE_IMM(x) (RV_X(x, 0, 12) << 20)

获得 value 后需要把 value 修改到原指令 word 中

word = (word & ~howto->dst_mask) | (value & howto->dst_mask);

其中 dst_mask 是 value 在 word 中的 mask, 例如 R_RISCV_HI20 的 HOWTO 定义为:

HOWTO(
    R_RISCV_HI20,           /* type */
    32,                     /* bitsize */
    false,                  /* pc_relative */
    0,                      /* bitpos */
    "R_RISCV_HI20",         /* name */
    0,                      /* src_mask */
    ENCODE_UTYPE_IMM(-1U),  /* dst_mask */
    false),

其中 dst_mask 为 ENCODE_UTYPE_IMM(-1U), 即 0xfffff000, 通过这个 mask 就可以把 word 中的 value 部分修改成 relocation 的结果了.