Linker Script

SECTIONS 是 linker script 最主要的部分, 通过 SECTIONS 把多个文件的 section 合并成一个 section, 并指定 section 的地址, 例如:

SECTIONS {
    /* 所有输入文件的 .text section 被合并在输出文件的 .text section 中
    * , 并且 .text section 的 vaddr 为 0x20000 */
    .text 0x20000: {
        *(.text)
    }
    /* 把 location counter 置于 0x40000 */
    . = 0x40000;
    /* 把 foo.o 中的 .data 和 bar.o 中的 .data2 合并到输出文件的 .data 中
    * 这里没有指定地址, 所以地址为 location counter 当前的值 (0x40000)*/
    .data : {
        foo.o(.data)
        bar.o(.data2)
    }
    /* 这里 location counter 的值会自动加上 sizeof(.data), 所以 .bss
    的地址会接着 .data */
    .bss : {
        *(.bss)
    }

    /* location counter 也可以这样赋值 */
    . = . + 0x10000

    /* 输入文件的 section 只能使用一次, 所以这里 .tmp 并不会有任何内容 */
    .tmp : {
        *(.bss)
    }
    // section 可以通过 `>` 使用其它的 memory region, 而非默认的 memory region,
    // 例如 .tmp2 会被放在 ram 的开头, 前面指定的 location counter 不影响 ram
    // section 还可以通过 AT(xxx) 指定 LMA
    .tmp2 : AT (0x1000) {
        /*...*/
    } > ram
    // section 通过 section 最后的 AT>xxx 指定 LMA 使用的 memory region
    .tmp3 : {
        /*...*/
    } AT> rom
    /* 所有其它未指定的 section 会自动按某种方式合并到输出文件中 */
}

MEMORY {
    ram (rwx) : ORIGIN = 0x1000, LENGTH = 10M
    ram2 (rwx) : ORIGIN = 0x1000000, LENGTH = 10M
}

.sec1 : {

} >ram

.sec1 : {

} >ram2

通过 MEMORY 定义了 ram, ram2, 通过 `>ram` 可以方便的指定 section 放在哪个地址,并用能跟踪内存使用是否超出范围. 如果不使用 memroy, 则需要:

.sec1 0x1000 : {}
.sec2 0x1000000 : {}

或者使用 location counter:

. = 0x1000;
.sec1 : {}
. = 0x1000000;
.sec2 : {}

稀疏的内存布局会导致 binary 很大, 无法打包在 rom 中. 通过 AT 或 section 中直接直接直接 LMA, 可以避免过大的 binary, 但需要运行时手动把数据从 LMA 复制到 VMA

SECTIONS
{
    hello_1 = .;
    .cpio : {
        hello_2 = .;
        *(._archive_cpio)
        hello_3 = .;
    } >ram AT> rom
    hello_4 = .;
    hello_5 = ADDR(._archive_cpio);
}

• hello_2,5 一定对应 section 的 vma 的起始地址
• hello_1 并不一定是 section 的 vma 起始地址, 因为 section 可能有对齐, 或者 section 通过 `<section> <addr> : {}` 直接指定了另一个 vma 地址
• hello_3,4 一定对应 vma 的结束地址
• 并不存在 ram1 或 ram2 的 location counter, 只有一个全局 location counter

SECTIONS
{
    . = 0x1000;
    ._cpio : {
        . = 0x10;
        *(._archive_cpio)
    } >ram AT> rom
}

• 在 section 内部对 location counter 赋值时指定的是相对于 section vma 起始地址的偏移量, `. = 0x10` 等价于 `. = . + 0x10`…
• section 内部的赋值会在 section 中产生 padding
• 在 section 外部对 location counter 赋值时使用的是绝对地址
• section 外部的赋值会在 section 之间产生 margin
• section 外部的赋值对使用了 `>ram` 形式的 section 没有作用…
• 为弥补前面的问题, 可以通过 `<section> <addr> BLOCK(align) : {} >ram` 设置 section 的起始地址和 align

xxx = 0xabc;

extern int xxx;
int main(int argc, char *argv[]) {
    printf("%x\n", &xxx);
}

$> ./a.out
b71b3abc

输出的结果中有 b71b3 前缀是因为 PIE 的原因

PROVIDE 与直接赋值差不多, 但有一点差别:

PROVIDE (xxx = 0xabc);

$> cat test.c
extern int xxx;
int main(int argc, char *argv[]) {
    printf("%x\n", &xxx);
}

$> arm-linux-androideabi-gcc test.c -fPIE -pie -O0 -g3 -T test.lds
$> ./a.out
af92babc

$> cat test2.c
int xxx = 0;
int main(int argc, char *argv[]) {
    printf("%x\n", &xxx);
}

$> arm-linux-androideabi-gcc test2.c -fPIE -pie -O0 -g3 -T test.lds
$> ./a.out
ab8c9004

可见, PROVIDE 只能给未定义的全局符号赋值.

$> gcc test.c -Wl,-verbose
$> ld --verbose

$> gcc test.c -Wl,--script=test.lds
$> gcc test.c -T test.lds